เปลี่ยนมาใช้ Syntax Highlighter 3.0.83

เพิ่งมาสังเกตุว่า ส่วนที่เป็น source code ที่ใช้ Syntax Highlighter มันไม่แสดงผลอย่างที่ควรจะเป็นครับ พอลองตรวจสอบดูปรากฏว่า ลิงค์ที่ไป URI ของ Syntax Highlighter version 1.5 ที่เคยใช้มัน Access Denied ครับ ลองหลายๆเวอร์ชันก็เป็นเหมือนกัน

ก็เลยได้โอกาสปรับเปลี่ยนมาลองใช้เวอร์ชันล่าสุด ซึ่งปัจจุบันเป็นเวอร์ชัน 3.0.83 ครับ ปรากฏว่าเวลาเราเขียน <pre> tag ต้องกำหนด attribute ใหม่ จากเดิมเป็น <pre name=code class=vb> เป็น <pre class="brush:vb"> ครับ

ไว้ว่างๆจะทยอยไล่แก้ที่บทความเก่าๆ ถ้าเป็นไปได้ก็จะหาที่เก็บไฟล์เวอร์ชันนี้เองน่าจะดี ^_^

Fix: IE8 Stuck on new tab

ตอนนี้ที่บริษัทเริ่มใช้ IE8 กันมากขึ้นแล้วครับ ทีนี้ก็เจอปัญหาว่าบางโปรแกรมที่เราเขียน เราสั่งให้มันเป็น Window ใหม่เช่นแสดงรายงาน หรือทำ Popup ปรากฏว่าอยู่ดีๆ ก็ไม่สามารถเปิด Window ใหม่ได้ครับ (มารู้ทีหลังว่าเป็นเพราะเราลงโปรแกรมบางตัว เช่น Image Viewer ครับ)

ทีแรกลองค้นใน google ดูก็พบว่าวิธีแก้ปัญหาคือต้องลงทะเบียน dll บางตัวใน registry ใหม่ ซึ่งมีหลายตัวมากครับ ให้เราลองสั่ง regsvr32 ทีละตัวดู ซึ่งก็เสียเวลามาก โชคดีที่เพื่อนที่ทำงานได้ bat file มา 1 ตัวซึ่งแก้ปัญหานี้ได้ พอไปดูในโค้ดก็เห็น link ไปเวบ http://iefaq.info ครับ พอเข้าไปดูปรากฏว่าไม่ใช่ภาษาอังกฤษซะงั้น

แต่สำหรับคนที่มีปัญหาเกี่ยวกับ IE ลองเข้าไปดูได้ครับ โดยเฉพาะ IE8 ถ้าสนใจตัว script สำหรับแก้ปัญหา registry ของ IE8 ให้ไปที่หน้า

http://iefaq.info/index.php?action=artikel&cat=47&id=136&artlang=de

สำหรับผมใช้ Windows7 32 bit เลยดาวน์โหลดตัว IE8-rereg.zip มาใช้ครับ สุดยอดมากๆๆ

แก้ปัญหา Export to Excel ด้วย GridView: Control 'GridView1' of type 'GridView' must be placed inside a form tag with runat=server.

วันก่อนผมเขียนโปรแกรมเพื่อ export ข้อมูลจาก GridView มาเป็น Excel ครับ (ก่อนหน้านี้ใช้ Datagrid ไม่เคยมีปัญหา) ก็เจอ error ดังนี้ครับ



นั่งงมอยู่ตั้งนาน ก็เลยเจอวิธีแก้ว่าให้เพิ่มโค้ดดังนี้ครับ

    Public Overrides Sub VerifyRenderingInServerForm(ByVal control As System.Web.UI.Control)
        'MyBase.VerifyRenderingInServerForm(control)

    End Sub

แค่นี้ก็ใช้งานได้แล้วครับ

แต่ถ้าใครเจอปัญหาว่า "RegisterForEventValidation can only be called during Render();"



ให้เอา AllowSorting กับ AllowPaging ออกครับ

เท่านี้เราก็สามารถใช้ GridView ในการสร้าง Excel ได้แล้วครับ

ปัญหาเมื่อ export excel: The file you are trying to open, 'name.xls', is in a different format than specified by the file extension

ช่วงนี้หลังจากที่ทำงาน migrate Office จาก 2003 เป็น 2007 ก็เจอปัญหาว่าโปรแกรมที่เราสร้างรายงาน Excel ด้วยวิธีการกำหนด Response.ContentType = "application/vnd.ms-excel" ได้ผลลัพธ์ตามปกติ แต่ว่าจะมี alert ขึ้นมาว่า

The file you are trying to open, 'name.xls', is in a different format than specified by the file extension. Verify that the file is not corrupted and is from a trusted source before opening the file. Do you want to open the file now?

จริงๆก็ไม่ได้มีปัญหาอะไรมากหรอกครับ เพราะแค่กด OK ก็เปิดดู Excel ได้ตามปกติ แต่หลังๆเริ่มมี user บ่นขึ้นเรื่อยๆ เลยลอง search ดูก็พบ article ที่เวบไมโครซอฟท์ครับ

When you open a file in Excel 2007, you receive a warning that the ...
Article ID: 948615 - Last Review: March 4, 2008 - Revision: 1.1
support.microsoft.com/kb/948615


วิธีแก้ก็ง่ายๆคือไปกำหนด registry นั่นเอง ผมก็เลยทำเป็นไฟล์ reg จะได้ส่งให้ user เฉพาะรายที่มีปัญหารันได้เลย (จริงๆแล้วเราสามารถใช้ Group Policy ในการแก้ปัญหานี้ได้ครับ ลองดูใน article ละกัน)

ก่อนอื่นก็สร้างไฟล์ชื่อ ExcelFileFormat.reg สำคัญตรงนามสกุลไฟล์ให้เป็น .reg นะครับ แล้วก็ใส่เขียนโค้ดดังนี้

REGEDIT4
[HKEY_CURRENT_USER\Software\Microsoft\Office\12.0\Excel\Security]
"ExtensionHardening"=dword:0

จากนั้นก็ save ไฟล์

พอต้องการใช้ ก็ double click ที่ไฟล์นี้ได้เลยครับ

ScriptMode ของ ScriptManager ต่างกันอย่างไร

วันนี้เจอคำถามที่ GreatFriends เรื่อง ScriptMode ของ ScriptManager ซึ่งผมตอบไปแล้ว แต่ก็จะมาขยายความเพิ่มใน blog นี้ละกันครับ

ใน ScriptManager จะมี Property ตัวหนึ่งชื่อ ScriptMode ซึ่งมี option ให้เลือก 4 ข้อ คือ Auto, Inherit, Debug, Release เพื่อความเข้าใจที่ง่ายขึ้นมาลองทดสอบกันเลยครับ



จากรูปผมสร้าง page ใหม่โดยให้มี ScriptManager แค่ 1 ตัว กำหนด ScriptMode เป็น debug แล้วลองรันทดสอบดูครับ (ถ้าใช้ IE ต้องไปเอา Disable Script Debugging ของ IE ใน Option ออกก่อนนะครับ ถึงจะ debug script ได้)



ลองดูใน Script Document ของ VS จะเห็นว่านอกจาก Default.aspx แล้วยังมี WebResource 1 ไฟล์กับ ScriptResource อีก 2 ไฟล์เพิ่มขึ้นมา ตอนนี้เรามา focus ที่ ScriptResource ครับ ลอง double click มาตัวหนึ่ง จะเห็นว่าข้างในมันคือ javascript นี่เอง มีใส่ comment และ เว้นบรรทัดสวยงามอ่านง่ายครับ สังเกตุชื่อใน comment ครับ ว่ามันคือ MicrosoftAjax.debug.js

คราวนี้ลองเปลี่ยน ScriptMode เป็น Release ดูบ้าง


ลองรันดูครับ


จะสังเกตุว่าไฟล์ที่นำมาทำ ScriptResource จะเปลี่ยนไปเป็น MicrosoftAjax.js แทน ซึ่งมี comment นิดเดียวและก็โค้ดเรียงติดกันเป็นพรืด

โดยปกติเราไม่ค่อยได้ debug javascript พวกนี้อยู่แล้ว ก็สามารถกำหนด ScriptMode เป็น Release เลยก็ได้ครับ เพราะขนาดไฟล์จะเล็กกว่า ไม่กิน bandwidth ครับ

ส่วนถ้าเราเลือก ScriptMode เป็น Auto ตอนที่รันจะขึ้นอยู่กับว่า Web เราเลือก Configuration เป็น debug หรือว่า release ครับ WebServer จะไปเลือกไฟล์ js ที่ตรงกับ config ของเรามาสร้าง ScriptResource ให้

VB.NET ออกรายงาน Excel แบบรวดเร็ว

โดยปกติเมื่อเราพัฒนาโปรแกรมทางธุรกิจ ที่หนีไม่พ้นก็คือต้องออกรายงานครับ และโดยส่วนใหญ่เรามักจะใช้ Crystal Report เพราะสะดวก ง่าย และรวดเร็วครับ ที่สำคัญเรายังสามารถ Export ข้อมูลออกเป็น Excel, Word หรือ PDF ก็ยังได้

แต่ถ้าเราไม่สามารถใช้ Crystal Report ได้ละ เช่นลูกค้าไม่มี License เป็นต้น ทางเลือกหนึ่งก็คือออกรายงานเป็น Excel ครับ ถ้าลูกค้ามี Licese ของ Microsoft Excel อยู่แล้วก็ไม่ยาก หรือเราอาจใช้ OWC (Office Web Componet) แทนก็ได้ ซึ่ง OWC สามารถดาวน์โหลดได้จากเวบของ Microsoft ครับ (ปัจจุบันผมใช้ OWC11) ซึ่งสามารถออกรายงาน รวมถึงสร้างกราฟได้ด้วย

แต่ข้อเสียของการใช้ Excel หรือ OWC คือ ช้าครับ แถมกิน CPU สูงมากโดยเฉพาะถ้าต้องวนลูปเพื่อใส่ข้อมูล วันนี้ผมจะนำเสนออีกวิธีในการออกรายงาน Excel ครับ นั่นคือเรานำข้อมูลที่ต้องการไปใส่ใน delimited file ก่อนเช่น .csv (CSV file), .txt (Tab delimited file), .prn (Spaced delimited, Formatted Text) หรือ .txt ที่เรากำหนด delimeter เอง เช่น ; หรือ : เป็นต้นครับ จากนั้นค่อยใช้ Excel หรือ OWC เปิดไฟล์พวกนี้ขึ้นมาเพื่อทำการตกแต่งรายงานให้สวยงาม เช่น ใส่ Header, กำหนดขนาด หรือ layout, ตีเส้นตาราง เป็นต้นครับ

ทีนี้มาลองดูการออกรายงานด้วย Tab Delimited ละกันครับ ผมเริ่มจากสร้าง Console Application มาตัวหนึ่ง แล้วก็ Add Reference ของ Microsoft Excel 12.0 Object Library ครับ



จากนั้นก็สร้างข้อมูลสำหรับทดสอบ โดยสร้าง Employee Class ขึนมา และ EmployeeManager Class สำหรับ สร้าง List ของ Employee ขนาด 100,000 ข้อมูลครับ

Public Class Employee
    Public EmployeeID As String
    Public FirstName As String
    Public LastName As String
    Public BirthDay As Date
    Public Salary As Double
End Class

Public Class EmployeeManager
    Public Shared Function GetEmployees() As IList(Of Employee)
        Dim employees As New List(Of Employee)
        Dim emp As Employee = Nothing
        For iRecord As Integer = 0 To 100000
            emp = New Employee With {.EmployeeID = iRecord, .FirstName = "Test" &  iRecord, .LastName = "LName", .BirthDay = DateSerial(1990, 1, 1), .Salary = 2000.0 + CDbl(iRecord)}
            employees.Add(emp)
        Next
        Return employees
    End Function
End Class

ทีนี้ก็มาเขียนโค้ดสำหรับการทดสอบกันครับ

Module Module1
    Const EU_DATE_FORMAT As String = "dd-MM-yyyy hh:mm:ss"
    Dim employees As IList(Of Employee)
    Dim startDate As Date = Now
    Dim endDate As Date = Nothing

    Private Sub DecorateExcel(ByVal xlsBook As Microsoft.Office.Interop.Excel.Workbook)

        Dim xlsSheet As Microsoft.Office.Interop.Excel.Worksheet = Nothing
        xlsSheet = xlsBook.ActiveSheet
        xlsSheet.Range("A:E").EntireColumn.AutoFit()

        With xlsSheet.Range("A1").Font
            .Bold = True
            .Size = "14"
        End With

        With xlsSheet.Range("A2").Font
            .Bold = True
            .Size = "12"
        End With

        With xlsSheet.Range("A3:E3")
            .Interior.Color = System.Drawing.Color.Silver.ToArgb
            .Font.Bold = True
        End With

        xlsSheet.Range("E:E").NumberFormat = "#,##0.00"

        Dim r As Microsoft.Office.Interop.Excel.Range
        r = xlsSheet.Range("A3:E20004")

        With r.Borders
            .LineStyle = Microsoft.Office.Interop.Excel.XlLineStyle.xlContinuous
            .Weight = Microsoft.Office.Interop.Excel.XlBorderWeight.xlThin
            .ColorIndex = 0
        End With

    End Sub

    Private Sub ExportByTAB()
        startDate = Now
        Console.WriteLine("Export by Tab delimited")
        Console.WriteLine("Start at " & startDate.ToString(EU_DATE_FORMAT))

        Dim _fileNameTAB As String = "C:\test.txt"
        Dim _fileName As String = "c:\testTAB.xlsx"

        Dim fs As System.IO.FileStream = System.IO.File.Create(_fileNameTAB)
        Dim writer As New System.IO.StreamWriter(fs)

        writer.WriteLine("List of Employee")
        writer.WriteLine("As of " & Now.ToString("dd MMM yyyy"))
        writer.WriteLine("Employee ID" & vbTab & "First Name" & vbTab & "Last Name" & vbTab & "Birth Date" & vbTab & "Salary")

        For Each emp As Employee In employees
            writer.WriteLine(String.Concat(emp.EmployeeID, vbTab, emp.FirstName, vbTab, emp.LastName, vbTab, emp.BirthDay.ToString("yyyy-MM-dd"), vbTab, emp.Salary))
        Next

        writer.Close()
        writer.Dispose()
        fs.Close()
        fs.Dispose()

        ' Open txt file with Excel for decoration
        Dim xlsAPP As New Microsoft.Office.Interop.Excel.Application
        Dim xlsBook As Microsoft.Office.Interop.Excel.Workbook
        xlsAPP.Visible = False
        xlsBook = xlsAPP.Workbooks.Open(_fileNameTAB)
        DecorateExcel(xlsBook)

        ' Save as Excel2007
        If System.IO.File.Exists(_fileName) Then System.IO.File.Delete(_fileName)
        xlsBook.SaveAs(_fileName, Microsoft.Office.Interop.Excel.XlFileFormat.xlOpenXMLWorkbook)
        xlsBook.Close(SaveChanges:=False)

        xlsAPP.Quit()

        System.Runtime.InteropServices.Marshal.ReleaseComObject(xlsAPP)
        GC.SuppressFinalize(xlsAPP)
        GC.Collect()
        xlsBook = Nothing
        xlsAPP = Nothing

        System.IO.File.Delete(_fileNameTAB)

        endDate = Now
        Console.WriteLine("Finish at " & endDate.ToString(EU_DATE_FORMAT))
        Console.WriteLine("Total " & (endDate - startDate).TotalMilliseconds & " milliseconds")
        Console.WriteLine("***********************")

    End Sub

    Sub Main()

        employees = EmployeeManager.GetEmployees()
        Console.WriteLine("Testing for " & employees.Count - 1 & " records.")
        Console.WriteLine("")
        ExportByTAB()
        Console.WriteLine("Finish test.")
        Console.ReadLine()

    End Sub

End Module

ลองรันผลทดสอบดูครับ เครื่องผม Pentium 4 2.66GHz RAM 2 GB ข้อมูลขนาด 100,000 เรคคอร์ดใช้เวลา 7 วินาทีกว่าๆ



ข้อมูลขนาด 5,000 เรคอร์ด ใช้เวลา 2.1 วินาที


ลองดูผลลัพธ์ครับ


เรียบร้อยครับ ทีนี้ถ้าเราอยากจัด Layout สวยๆ เราสามารถเปิด Excel แล้วสั่งบันทึก Macro แล้วค่อยเอา source code ที่ได้ไปใส่เพิ่มใน DecorateExcel Function ครับ

ปล.
1. ผมลอง export โดยใช้ CSV ก็ได้ความเร็วไม่ต่างกันมากครับ
2. ผมลองวนลูปเก็บข้อมูลเข้า StringBuilder ก่อน แล้วค่อยเขียนไฟล์ ปรากฏว่าใช้เวลามากกว่าเปิดไฟล์แล้ววนลูปเขียนเข้าไปตรงๆเลยครับ

VB6 ติดต่อ ASP.NET WebService

ช่วงนี้มีโอกาสกลับไปแก้โปรแกรมเก่าที่เขียนด้วย VB6 ครับ และแน่นอนงานที่แก้ก็คือให้โปรแกรมมันทำงานกับ WebServices ได้นั่นเอง หลังจากลองๆค้นไปค้นมา ก็เลยทำโปรแกรมทดสอบมาก่อนครับ

เริ่มต้นที่ ASP.NET WebServices กันก่อน แรกสุดก็สร้าง Employee Class ครับ

<Serializable()> _
<System.ComponentModel.DefaultProperty("EmployeeID")> _
Public Class Employee

    Private _employeeId As String
    Private _employeeName As String
    Private _employeeSurnam As String

    Public Property EmployeeSurname() As String
        Get
            Return _employeeSurnam
        End Get
        Set(ByVal value As String)
            _employeeSurnam = value
        End Set
    End Property

    Public Property EmployeeName() As String
        Get
            Return _employeeName
        End Get
        Set(ByVal value As String)
            _employeeName = value
        End Set
    End Property

    Public Property EmployeeId() As String
        Get
            Return _employeeId
        End Get
        Set(ByVal value As String)
            _employeeId = value
        End Set
    End Property

    Public Overrides Function ToString() As String
        Return EmployeeId
    End Function

    Public Function Save() As Boolean
        Return True
    End Function

End Class

ที่จริงมี EmployeeManager Class ด้วย แต่ว่าขี้เกียจเอามาลงให้ดู ทีนี้ก็มาสร้าง WebServices กันครับ

Imports System.Web
Imports System.Web.Services
Imports System.Web.Services.Protocols

<WebService(Namespace:="http://jnithi/")> _
<WebServiceBinding(ConformsTo:=WsiProfiles.BasicProfile1_1)> _
<Global.Microsoft.VisualBasic.CompilerServices.DesignerGenerated()> _
Public Class EmployeeWS
    Inherits System.Web.Services.WebService

    <WebMethod()> _
    Public Function GetEmployee(ByVal empID As String) As Employee
        Dim emp As Employee = Nothing
        emp = EmployeeManager.GetEmployeeByID(empID)
        Return emp
    End Function

    <WebMethod()> _
    Public Function UpdateEmployee(ByVal empID As String, ByVal empName As String, ByVal empSurname As String) As Boolean
        Dim emp As Employee = Nothing
        Dim result As Boolean = False
        emp = EmployeeManager.GetEmployeeByID(empID)
        emp.EmployeeName = empName
        emp.EmployeeSurname = empSurname
        result = emp.Save
        Return result
    End Function

End Class

ลองรัน WebServices ดูครับ ไปที่ http://nithi/TestWeb/EmployeeWS.asmx จะเห็นว่ามี Service 2 ตัว ตามที่เราสร้างไว้ครับ กดเลือก GetEmployee เพื่อดู Service Description

ดูที่ SOAP 1.1 ครับ เดี๋ยวเราจะนำข้อมูลตรงนี้ไปใช้ในการเรียก WebService

ส่วนของ SOAP Request


ส่วนของ SOAP Response


คราวนี้มาที่ VB6 บ้าง เริ่มจากสร้าง Project ใหม่ จากนั้นก็สร้าง Class ชื่อ clsEmployee ครับ ให้มี Property 3 ตัวเหมือนฝั่ง .NET ทีนี้ก็มาสร้าง Class สำหรับจัดการ WebService ครับ ตั้งชื่อ clsEmployeeWS ก่อนอื่นก็ Add Reference ก่อนครับ เลือก Microsoft XML, v4.0 (ผมลองตั้งแต่ v 2.6 ก็ใช้ได้หมดครับ เลยเลือกอันกลางๆ)แล้วก็เขียนโค้ดได้เลย

Dim asmxURL As String
Dim soapAction As String
Dim soapEnvelop As String
Dim domResult As MSXML2.DOMDocument

Private Function GetResponse(URL As String, action As String, envelop As String) As MSXML2.DOMDocument
    Dim xmlHTTP As New MSXML2.xmlHTTP
    Dim domReturn As New MSXML2.DOMDocument
    Dim domDOC As New MSXML2.DOMDocument
    
    domDOC.loadXML envelop
    
    xmlHTTP.Open "POST", URL, False
    
    ' Create headings
    xmlHTTP.setRequestHeader "Content-Type", "text/xml; charset=utf-8"
    xmlHTTP.setRequestHeader "SOAPAction", action
    
    ' Send
    xmlHTTP.send domDOC.xml
    domReturn.loadXML xmlHTTP.responseText
   
    
    Set xmlHTTP = Nothing
    Set domDOC = Nothing
    Set GetResponse = domReturn
End Function

ผมสร้าง Function ชื่อ GetResponse ไว้สำหรับติดต่อกับ WebServices ครับ Function นี้จะคืนค่าเป็น XMLDOMDocument มาให้ครับ ถ้าเราเรียก WebServices สำเร็จ ลอง debug ดูค่า domReturn.xml เพื่อดูผลลัพธ์ได้ครับ

เสร็จแล้วก็สร้าง Function สำหรับเรียกใช้งาน WebServices ครับ โดยใน GetEmployee Function เราจะระบุ parameter ที่ต้องการได้แก่ asmxURL, soapAction (ดูจาก SOAP Request ในรูปด้านบนครับ) แล้วก็ Envelop (copy มาจาก SOAP Request เหมือนกัน) แต่อย่าลืมเปลี่ยน parameter นะครับ ตรงบรรทัด " & empID & "

Public Function GetEmployee(empID) As clsEmployee
    asmxURL = "http://nithi/testweb/EmployeeWS.asmx"
    soapAction = "http://jnithi/GetEmployee"
    soapEnvelop = " " & _
                  "      " & _
                  "          " & _
                  "             " & _
                  "                 " & empID & " " & _
                  "              " & _
                  "          " & _
                  "      "
    Set domResult = GetResponse(asmxURL, soapAction, soapEnvelop)
    
    Dim oNode As MSXML2.IXMLDOMNode
    Dim oNodes As IXMLDOMNodeList

    'ดึง ... ผลลัพธ์ได้เป็น List (XMLDOMNodeList)
    Set oNodes = domResult.getElementsByTagName("GetEmployeeResult")
    Dim employee As clsEmployee

    If oNodes.length > 0 Then
        Set oNode = oNodes.Item(0)
        Set employee = New clsEmployee
        employee.EmployeeID = oNode.selectSingleNode("EmployeeId").Text
        employee.EmployeeName = oNode.selectSingleNode("EmployeeName").Text
        employee.EmployeeSurname = oNode.selectSingleNode("EmployeeSurname").Text
    End If
    Set GetEmployee = employee
End Function

คราวนี้มาทำหน้าจอทดสอบครับ

Private Sub ClearEmployee()
        Me.txtEmpID.Text = ""
        Me.txtEmpName.Text = ""
        Me.txtEmpSurname.Text = ""
End Sub

Private Sub cmdClear_Click()
    ClearEmployee
    Me.txtSearchID.Text = ""
End Sub

Private Sub cmdSearch_Click()
    Dim ws As New clsEmployeeWS
    Dim employee As clsEmployee

    'เรียก clsEmployeeWS ให้ติดต่อ WebServices
    Set employee = ws.GetEmployee(Me.txtSearchID.Text)
    If employee Is Nothing = False Then
        Me.txtEmpID.Text = employee.EmployeeID
        Me.txtEmpName.Text = employee.EmployeeName
        Me.txtEmpSurname.Text = employee.EmployeeSurname
    Else
        ClearEmployee
        MsgBox "Cannot find employee.", vbInformation + vbOKOnly, App.Title
    End If
End Sub

ลองรันดูผลลัพธ์ครับ



เรียบร้อย ไม่ยากครับ

จริงๆตอนทดสอบ ผมยังลองทำการ Insert, Update, Delete แล้วก็ SELECT ข้อมูลเป็น Array มาด้วย แต่คงไม่ได้เอามาลง Blog ให้ดูครับ เพราะถ้ารู้ concept แล้วที่เหลือก็ไม่ยากแล้วครับ

ลอง Chrome และ FireFox 3.6

ผมเคย download หมาย่างมาลองใช้ตั้งแต่เวอร์ชัน 1.x จนล่าสุดในเครื่องเป็นเวอร์ชัน 2.x แต่แค่ลองคลำๆดูก็เลิกกลับมาใช้ IE เหมือนเดิม เพราะว่าใช้ FF แล้วเข้าไป Pantip แล้ว font มันไม่สวย ตัวเล็ก อ่านยากกกกก และเวบไทยหลายๆเวบแนะนำให้ใช้ IE มากกว่า

จนเมื่อวานนี้ได้ลองดาวน์โหลด Chrome มาใช้ มันเยี่ยมมาก เร็วและดี เลยลอง search ใน google เรื่อง Browser ต่างๆเพิ่มเติม จนเจอว่า FF มันมี option ให้ set font ได้ (จริงๆถ้าตั้งใจเล่นก็น่าจะ set เองได้ตั้งนานแล้ว มัวแต่ติด IE) พอลอง set ตามและเข้า Pantip และเวบอื่นๆที่เล่นบ่อยๆดู โอ้ว จอร์จ ไม่น่าโง่ตั้งนาน ก็เลยรีบไปดาวน์โหลด FF3.6 ภาษาไทยที่ http://www.mozilla.com/th/ และก็ติดตั้ง Extension พวก FireBug, WebDeveloper มาลองเล่นดู เพราะเคยอ่านเจอใน Textbook ครับ อยากลองเล่นมานานแล้วแต่ขี้เกียจลง FF

เมื่อคืนก็เลยลอง Chrome กับ FF อยู่ 3-4 ชั่วโมง สรุปว่าส่วนตัวผมชอบ Chrome มากกว่า ตอนนี้เลยใช้ Chrome เป็นหลัก ยกเว้นเข้าบางเวบก็จะใช้ IE ครับ ส่วน FF ก็ชอบอยู่นะก็จะลองใช้สลับกับ Chrome ดูครับ

ว่างๆจะลองโหลด IE8 กับ Opera มาเล่นดูบ้าง ไม่ได้เล่น Opera มานานมากแล้ว

ปล. วันนี้ป่วยลางานอยู่บ้านครับ เพราะเป็นฝีฝักบัวโดนหมอผ่าก้อนฝีออกเท่ามะนาวลูกย่อมๆ (หมอบอก เพราะผมหลับตาปี๋ไม่กล้ามอง) หมอยังไม่เย็บแผลเลย ตอนนี้เอาผ้าก็อซใหญ่กว่าหัวแม่โป้ง (อันนี้เห็นตอนทำแผล) ยัดเข้าไปแล้วปิดแผลไว้ รอดูอาการถ้าดีขึ้นถึงจะเย็บแผล ระหว่างพิมพ์ blog ยังมีรูโบ๋อยู่ที่หน้าท้องอยู่เลย 555

ปล.2 ตอนทำความสะอาดแผล เจ็บโครตๆๆๆ แต่ยังน่าจะน้อยกว่าผู้หญิงคลอดลูกเยอะ T_T ดังนั้นชาติหน้าขอเกิดเป็นผู้ชายอีกนะคร้าบบบบ

ส่ง URL Parameter ให้ ClickOnce Application

ผมเคยเขียน blog เรื่อง สั่งรัน Win App บนเครื่อง Client เมื่อเดือนธันวาคม 2009 แล้วก็ติดเรื่องส่ง paramenter ให้ ClickOnce application เอาไว้ครับ วันนี้มีโอกาสก็เลยมาเขียนเรื่องนี้ซะเลย

ก่อนอื่นเราก็มาสร้าง Console Application สำหรับการทดสอบซะก่อนครับ จากนั้นก็ Add .NET Reference เข้ามาในโปรเจคเรา 2 ตัว คือ System.Deployment กับ System.Web ครับ แล้วก็เขียนโค้ด Import NameSpace ที่จำเป็นเข้าในด้วย

Imports System.Collections.Specialized
Imports System.Deployment.Application
Imports System.Web

Module Module1

    Sub Main()
        Dim params = GetURLParameter()
        If params.Count > 0 Then
            For i As Integer = 0 To params.Count - 1
                Console.WriteLine("Parameter {0} is {1}", params.Keys(i), params.Item(i))
            Next
        Else
            Console.WriteLine("No URL Parameter")
        End If
        Console.WriteLine("Press any key to quit.")
        Console.ReadLine()

    End Sub

    Private Function GetURLParameter() As NameValueCollection
        Dim NameValueTable As New NameValueCollection

        If (My.Application.IsNetworkDeployed) Then
            Dim QueryString As String = ApplicationDeployment.CurrentDeployment.ActivationUri.Query
            NameValueTable = HttpUtility.ParseQueryString(QueryString)
        End If

        Return NameValueTable
    End Function

End Module

โค้ดที่ใช้ทดสอบมีเท่านี้ ไม่ยากใช่ไหมครับ แต่ที่สำคัญอีกอย่างหนึ่งก็คือ เราต้องกำหนดให้ ClickOnce Application ของเราสามารถรับ URL Parameters ได้ก่อน โดยไปที่ Property ของโปรเจค แล้วเลือก Publish Tab ครับ



ทีนี้เราจะเห็นปุ่ม OPTIONS กดเข้าไปได้เลยครับ



แล้วก็ทำการเลือก Manifests และคลิ๊กเครื่องหมายถูกตรง Allow URL parameters

เสร็จแล้วก็ทำการ Publish ครับ ทีนี้เรามาลองทดสอบเรียก ClickOnce Application แบบไม่ส่ง parameter ก่อน



โปรแกรมขึ้นว่า No parameter ถูกต้อง คราวนี้ลองทดสอบแบบส่ง QueryString ไปด้วย
(http://nithi/COParameter/CoParameter.application?param1=test1&param2=test2&name=nithi)



เรียบร้อยครับ คราวนี้เราก็สามารถส่ง URL Parameter ไปให้ Application ของเราได้แล้วครับ

Reference:
How to: Retrieve Query String Information in a ClickOnce Application

สถิติของ blog จาก Google Analytics

หลังจากผมได้ลองใช้ Google Analytics มาประมาณ 6 เดือน พอจะสรุปผลคร่าวๆดังนี้ครับ

1. ผู้เยี่ยมชมส่วนใหญ่มาจาก google ครับ ประมาณ 75%
2. เนื้อหายอดนิยมได้แก่ Crystal Report, RDLC, ITextSharp, jQuery น่าจะมาจากการค้นหาใน google
3. 30 วันแรกของ Blog ผู้เยียมชมโดยตรงมี 78 page view คิดเป็นอัตราส่วนประมาณ 11% ส่วนเดือนล่าสุดเพิ่มเป็น 281 (19.18%)
4. วันที่คนมีอัตราเยี่ยมชมสูงสุดคือวันพฤหัส ตอนนี้ pageview สูงสุดอยู่ที่ 72 pv ต่อวันครับ (ยังน้อยอยู่เทียบกับบาง blog ที่มีผู้เยี่ยมชมหลักพัน) วันที่คนเยี่ยมชมน้อยสุดคือวันอาทิตย์ ประมาณ 15-20 pv รวม 30 วันล่าสุดอยู่ที่ 1,465 pv
5. อัตราการเข้าชมโดยตรง ผมแปลกใจมากเพราะอันดับ 1 มาจาก CodeToday.net ครับ (จำได้ว่าผมไป post url ของ blog แค่ครั้งเดียว) อยู่ที่ 2.8% อันดับสองคือ blogger อยู่ที่ 1.57% ส่วน greatfriends อยู่ที่อันดับ 3 ที่ 0.89%

จากที่ได้ลองใช้มา รู้สึกว่า Google Analytics นี่ใช้ง่ายและเครื่องมือเยอะดีครับ แต่ยังต้องศึกษาอีกเยอะทีเดียว เดี๋ยวรอครบ 1 ปี จะมาลองดูใหม่ว่าอัตราการเยี่ยมชมมีอะไรเปลี่ยนแปลงบ้างครับ

ASP.NET สั่งเคลียร์ Session เมื่อเปลี่ยน Page

วันนี้เจอคำถามที่ greatfriends ว่าเมื่อ User ปิด Browser หรือเปลี่ยน Page เราต้องการไปเคลียร์ Session ของ Page เดิมจะทำยังไงดี

ถ้าเป็นเรื่องปิด Browser หรือว่า User ไปเปิดเวบอื่นคงไม่มีปัญหาครับ เพราะ ASP.NET มันจะเคลียร์ค่าให้เมื่อ Session Time Out อยู่แล้ว ซึ่งเราก็สามารถเขียนโค้ดใน Session_End ที่ Global.asax เพิ่มเติมก็ได้ แต่ปัญหาคือถ้า user เปลี่ยนหน้า เราจะทำยังไงดี สิ่งแรกที่ผมคิดคือ เรากำหนดให้มัน Post Back กลับมาหน้าเดิมก่อน เพื่อสั่ง Clear Session จากนั้นเราค่อยสั่ง Navigate ไปยังหน้าที่ต้องการอีกที

เช่นสมมติ เรามี User Control 1 ตัว เป็นเมนูสำหรับ Application เราใช้ <asp: Menu> และสร้าง <asp:MenuItem> เพื่อระบุเมนูย่อย แทนที่เราจะใช้ NavigateUrl Attribute เพื่อสั่ง Redirect ไปหน้าใหม่ทันที่ เราก็มาเขียนโค้ดที่ MenuItemClick Event แทนครับ

พอตอนเย็นก็นึกวิธีใหม่ออก ก็เลยมาลองดูครับ วิธีนี้คือ เราใช้ ASP.NET AJAX มาเรียก WebService เพื่อทำการ Clear Session นั่นเองครับ ลองมาดูโค้ดของ WebService กันก่อน

Imports System.Web
Imports System.Web.Services
Imports System.Web.Services.Protocols

Namespace jNithi.WS
    <System.Web.Script.Services.ScriptService()> _
    <WebService(Namespace:="http://tempuri.org/")> _
    <WebServiceBinding(ConformsTo:=WsiProfiles.BasicProfile1_1)> _
    <Global.Microsoft.VisualBasic.CompilerServices.DesignerGenerated()> _
    Public Class SessionManager
        Inherits System.Web.Services.WebService

        <Script.Services.ScriptMethod()> _
        <WebMethod()> _
        Public Function ClearSession(ByVal sessionName As String) As Boolean
            Dim session As System.Web.SessionState.HttpSessionState
            session = System.Web.HttpContext.Current.Session

            If session(sessionName) IsNot Nothing Then
                Select Case sessionName.ToUpper
                    Case "SESSION_RECEIPT_REPORT"
                        DirectCast(session(sessionName), CrystalDecisions.CrystalReports.Engine.ReportDocument).Dispose()
                    Case "SESSION_RECEIPT_DATA"
                        DirectCast(session(sessionName), IList).Clear()
                    Case Else
                End Select
                session(sessionName) = Nothing
                session.Remove(sessionName)
            End If

        End Function

    End Class

End Namespace

ทีนี้ในหน้า aspx เราก็เขียน javascript สำหรับมาเรียก Webservice ตัวนี้ครับ

<script type="text/javascript">
    function Body_OnUnload() {
         jNithi.WS.SessionManager.ClearSession('SESSION_RECEIPT_REPORT');          
    }
        
</script>
</head>
<body onunload="Body_OnUnload();">
    <form id="form1" runat="server">

    <asp:ScriptManager ID = "ScriptManager1" runat="server" >
        <services>
            <asp:ServiceReference Path="~/wsSession.asmx" />
        </services>
        
    </asp:ScriptManager>

เท่าที่ลองทดสอบดู ก็ใช้งานได้ผลโอเคนะครับ เมื่อเราเปลี่ยนหน้า หรือปิด Browser มันจะไปเรียก WebService เพื่อสั่ง Clear Session ให้ แต่มีข้อแม้นิดหนึ่งครับ คือ onunload event ของ Body นั้นมันจะทำงานทุกครั้งที่มีการเปลี่ยนหน้า นั่นคือ ถ้ามีการ PostBack กลับไป มันก็จะเกิด Event นี้ด้วยครับ แต่ถ้าเราออกแบบ ASP.NET AJAX Page ของเราดีๆ ไม่ให้มีการ Post Back กลับไป แนวคิดนี้ก็ทำงานได้โอเคครับ

เดี๋ยวคงต้องขอทดสอบอีกซักพัก ก่อนจะเอาไปใช้จริงครับ

Crystal Report - สร้างรายงานให้ user กำหนดเงื่อนไข Group ได้เอง (Dynamic Group By)

วันนี้เรามาดูเทคนิคของ Crystal Report อีกครั้งครับ (เนื่องจากดูใน Google Analytics เห็นคนชอบบทความเกี่ยวกับ Crystal Report เป็นพิเศษ) คราวนี้เราจะมาสร้างรายงานที่สามารถให้ user กำหนด Group By ได้เองตามใจ Blog นี้จะทำแค่ Group by 1 ระดับให้ดู แต่เราสามารถประยุกต์ใช้ให้ user เลือก group ได้มากกว่า 1 ระดับ รวมถึงสามารถกำหนดเงื่อนไข sort by ได้ด้วย

ก่อนอื่นเลยสิ่งที่จำเป็นก็คือ เราต้องสร้าง Parameter Field ขึ้นมาก่อน เพื่อรับค่า parameter จาก user ว่าต้องการให้ group by column ไหนของข้อมูลครับ จากตัวอย่างผมสร้าง Parameter Field ชื่อ pGroupBy




จากนั้นก็สร้าง Formula Field เพื่อนำค่าที่ได้จาก Parameter Field มาคำนวนหา column ที่ต้องการ group ครับ
ในตัวอย่างผมสร้าง Formula Field ชื่อ GroupBy



จากโค้ดใน Formula Editor ผมใช้ IF THEN ELSE ซ้อนกัน (ที่จริงน่าใช้ Switch Case แต่ผมขี้เกียจแก้แล้ว) สังเกตุว่าถ้า user ส่ง parameter มาเป็น Dept ผมจะให้ Group By Formula Field อีกที นอกนั้นก็จะ Group By Database Field ตามปกติครับ

คราวนี้มาดูหน้าเวบกันบ้างครับ ผมก็สร้าง Drop-down List มา 1 ตัว ชื่อ ddlGroupBy และใส่ List ที่ต้องการไว้

</asp:DropDownList ID="ddlGroupBy" runat="server" style="position:absolute;left:100px;top:10px" CssClass="txtOptional"  Width="110px" EnableTheming="False" EnableViewState="False" >
     </asp:ListItem Text="Client" Value="Client" Selected="True"></asp:ListItem>
     </asp:ListItem Text="Most Work Lawyer" Value="MostWorkLawyer"></asp:ListItem>
     </asp:ListItem Text="Resp. Lawyer" Value = "RespStaff"></asp:ListItem>
     </asp:ListItem Text="Department" Value="Dept" ></asp:ListItem>
</asp:DropDownList>

ตอนสร้างรายงานก็อย่าลืม SetParameterValue ด้วยครับ

Dim reportDoc As New ReportDocument
reportDoc.FileName = Server.MapPath("~/Reports/AR/rptAgingReport.rpt")
reportDoc.SetDataSource(ARReportResults)
reportDoc.SetParameterValue("pGroupBy", ddlGroupBy.SelectedValue)
reportDoc.SetParameterValue("AsOfDate", asOfDate)

เท่านี้ก็เรียบร้อยแล้วครับ ทีนี้ user ก็สามารถเลือก column ที่ต้องการ Group By ได้ตามใจครับ

Crystal Report - แสดงข้อความหลายคอลัมภ์ด้วย RTF Text Interpretation

วันก่อนได้รับ requirement ว่าในรายงานตัวหนึ่ง ต้องการให้แสดง Report Footer เพื่อแสดงข้อมูลตามเงื่อนไข โดยข้อมูลดังกล่าวต้องสามารถ ทำตัวหนา ตัวเอียง สำหรับข้อมูลที่ต้องการเน้น และจัดรูปแบบเป็น 2 คอลัมภ์ ซึ่งใน Report Footer มีทั้งหมด 5 ส่วน ส่วนดังกล่าวเป็นส่วนที่ 4

เริ่มแรกผมสร้าง Parameter Field มา 1 ตัว ชื่อ PaymentAccount และสร้าง Text Object มา 1ตัว และลาก Payment Account มาใส่ใน Text Object เพื่อให้เป็น Embedded Field เราจะได้สามารถกำหนด Text Interpretation ได้ครับ (จากรูปสังเกตุว่าเป็น Report Footer d)



เสร็จแล้วคลิ๊กเมาส์ขวาที่ Text Object ที่สร้างขึ้น เลือก Property แล้วคลิ๊กเครื่องหมายถูกที่ Can Grow ใส่ตัวเลข 0 คือไม่จำกัดบรรทัดลงไป เพื่อให้ Object นี้มันยืดได้

ต่อไปก็กำหนด Text Interpretation โดยการ double click ที่ Text Object แล้วเลือก Embedded field คลิ๊กเมาส์ขวา เลือก Format Embedded Field



เสร็จแล้วก็เลือก Paragraph Tab เลือก Text Interpretation เป็น RTF Interpretation



เสร็จขั้นตอนของรายงานแล้ว ทีนี้ก็มาเขียนโค้ดสำหรับสร้างข้อมูล RTF ครับ

Public Shared Function GetAccount(ByVal coCode As String) As String
   Dim sb As New Text.StringBuilder

   'Set RTF1, ANSI Page and Font-family
   sb.AppendLine("{\rtf1\ansi\ansicpg1252\deff0\deflang1033\deflangfe1033{\fonttbl{\f0\fswiss\fprq2\fcharset0 Arial;}}")

   'Set Tab (at 0.5 in and 2.5 in) and Font-size
   sb.AppendLine("\viewkind4\uc1\pard\nowidctlpar\sa200\sl276\slmult1\tx720\tx3600\f0\fs20")

   'Insert first blank line
   sb.AppendLine("\tab \par ")
   Select Case coCode
       Case "Nithi"
           sb.AppendLine("\tab Account Name \tab Nithi Juabsami \par ")
           sb.AppendLine("\tab Savings Account No.: \tab 1-1111-1111, USD account. \par")
           sb.AppendLine("\tab Bank Name: \tab Citibank, N.A. \par ")
           sb.AppendLine("\tab Bank Address: \tab 82 North Sathorn Road \par ")
           sb.AppendLine("\tab \tab Silom, Bangrak, \par ")
           sb.AppendLine("\tab \tab Bangkok 10500, Thailand \par ")
           sb.AppendLine("\tab -or- \par ")
           sb.AppendLine("\tab Account Name: \tab Nithi Juabsamai \par ")
           sb.AppendLine("\tab Savings Account No.: \tab x-xxxx-xxxx \par ")
           sb.AppendLine("\tab Bank Name: \tab The Siam Commercial Bank Plc., Thanon Witthayu Branch \par ")
           sb.AppendLine("\tab Bank Address: \tab 132 Wireless Road, Lumpini, Bangkok 10330 \par ")
       Case "jNithi"
           sb.AppendLine("\tab Account Name: \tab jNithi O.P.  \par  ")
           sb.AppendLine("\tab Bank Account No.: \tab xxx-xxxxxx-xxx (USD), Current Account  \par  ")
           sb.AppendLine("\tab Name of Bank: \tab The Siam Commercial Bank Plc., Thanon Witthayu Branch.  \par  ")
           sb.AppendLine("\tab Bank Address: \tab 132 Wireless Road, Lumpini, Bangkok 10330 \par ")
      Case Else
   End Select

   ' Insert bottom blank line
   sb.AppendLine("\tab \par ")

   ' SET end of RTF
   sb.AppendLine("}")
   Return sb.ToString
End Function

มาดูรายละเอียดกันครับ
{\rtf1\ansi\ansicpg1252\deff0\deflang1033\deflangfe1033{\fonttbl{\f0\fswiss\fprq2\fcharset0 Arial;}}
บรรทัดนี้เรากำหนด RTF Format และกำหนดให้ใช้ ANSI PAGE 1252 และ font คือ Arial

\viewkind4\uc1\pard\nowidctlpar\sa200\sl276\slmult1\tx720\tx3600\f0\fs20
บรรทัดนี้เรากำหนดให้เอกสารเรามี tab 2 อัน อันแรกคือ tx720 แปลว่าอยู่ที่ 720 twips หรือ 0.5 นิ้ว (โดยปกติ 1นิ้ว จะเท่ากับ 1440 twips) และอันที่สองคือ tx3600 คือ 3600 twips หรือ 2.5นิ้ว ส่วน fs20 คือขนาดของ font เท่ากับ 10 pt ครับ

\tab Account Name \tab Nithi Juabsami \par
แปลว่าพิมพ์ tab 1 ครั้ง (คือเลื่อนไปตำแหน่งที่ 0.5 นิ้วที่กำหนด) พิมพ์คำว่า Account Name แล้วพิมพ์ tab (เลื่อนไปยังตำแหน่ง 2.5 นิ้ว พิมพ์ Nithi Juabsamai แล้วขึ้นบรรทัดใหม่ (\par)

ตอนเขียนโค้ดสั่ง Report ก็เรียกฟังก์ชันนี้เพื่อส่ง parameter ให้ Crystal Report

rpt = New rptTestReceipt
rpt.SetDataSource(_receipt)
rpt.SetParameterValue("AsOfDate", AsOfDate.ToString("dd MMM yyyy"))
rpt.SetParameterValue("PaymentAccount", PaymentAccount.GetAccount(_receipt(0).CoCode))

คราวนี้ลองรันดูผลลัพธ์ครับ



เรียบร้อยครับ ตอนนี้ข้อมูล Payment Account ของเราก็แสดงเป็น 2 column (ซึ่งเราแบ่งด้วย Tab) ถ้าต้องการเพิ่ม Column เราก็สามารถกำหนด tab ที่ตำแหน่งที่ต้องการเพิ่มได้ครับ

ที่จริงเราสามารถกำหนด HTML Interpretation ได้ครับ แต่ว่า Cystal Report รองรับแค่ subset ของ HTML ครับ คือรองรับได้แค่บาง tag ซึ่ง tag อย่าง table ไม่รองรับครับ ผมเลยเปลี่ยนมาใช้ RTF Interpretation แทน

หมายเหตุ
จริงๆแล้วเราสามารถใช้ Word Pad ที่มาพร้อม Windows ในการจัดเอกสารตามต้องการ สามารถกำหนดตัวหนา ตัวเอียงได้ตามสะดวก แล้ว save เป็น rtf ไฟล์ จากนั้นก็ใช้ Note Pad เปิดมา copy ใส่ได้เลยครับ แต่อย่าใช้ Microsoft Word นะครับ เพราะมันจะใส่ tag เพิ่มเติมมาเยอะแยะจนน่าเวียนหัว

SQL Server - เก็บผลลัพธ์จาก Stored Procedure ลงในตาราง

ปกติผมก็ใช้ Stored Procedure ใน SQL Server เสมอๆครับ ซึ่งพอเรา execute stored procedure ก็จะได้ result set มาใช้งาน แต่ทีนี้ถ้าเราต้องการทำ query result set ที่ได้ละจะทำยังไงดี ถ้าเป็นเมื่อก่อนผมก็ copy stored procedure มาสร้างใหม่แล้วแก้คำสั่งข้างในให้ทำ query เพิ่มไปเลย เช่นไป join object อื่น หรือสั่ง where สั่ง group by ฯลฯ แล้วแต่ต้องการ

หรืออีกวิธีก็สั่ง CREATE TABLE ก่อน แล้วก็ INSERT ข้อมูลที่ได้จาก Stored Procedure ซึ่งวิธีนี้ถ้ามันมีหลาย field ตอนสั่ง CREATE TABLE ก็เหนื่อยไม่ใช่เล่น ซึ่งวิธีนี้ใช้บ่อยโดยเฉพาะอย่างยิ่ง stored procedure ของระบบ เช่นพวก sp_who2, sp_lock เป็นต้น ลองดูตัวอย่างครับ

CREATE TABLE #locks (spid int, dbid int, objid int,
 indid int, [type] varchar(4), resource varchar(50), mode varchar(2), status varchar(10));

INSERT INTO #locks (spid, dbid, objid, indid, [type], resource, mode, status)
EXEC dbo.sp_lock;

SELECT * FROM #locks;

DROP TABLE #locks;

อันนี้ตัวอย่างแค่ 8 fields ยังเหงื่อตก เพราะเทสกันหลายรอบครับ ทีแรกผมกำหนด datatype ไม่ถูกมันก็ error ใส่ ขนาดน้อยไปเช่น resource varchar(10) ก็ error ครับ

วันนี้ผมมีวิธีใหม่มาเสนอครับ ลองดูโค้ดละกัน

SELECT * INTO #tmpWho FROM OPENROWSET('SQLNCLI', 'Server=testSQLServer;Trusted_Connection=yes;', 'EXEC sp_who') ;

SELECT * FROM #tmpWho Where dbname='master' and loginame = 'sa';

DROP TABLE #tmpWho;

ครับ โค้ดนี้เราใช้คำสั่ง OPENROWSET ร่วมกับ SELECT INTO นั่นเอง สะดวกดีมากทีเดียว 555

คราวนี้มาดูตัวอย่างการใช้งานจริงบ้าง

SELECT * INTO tempTestOutput FROM OPENROWSET ('SQLNCLI', 'Server=testSQLServer;Trusted_Connection=yes;', 'EXEC testDB.dbo.spTestOutput ''testParameter1'''); 

SELECT t.*, e.Department, e.HiredDate
FROM tempTestOutput t INNER JOIN Employee e ON t.EmployeeId = e.EmployeeId
WHERE e.ResignedDate IS NULL
ORDER BY t.EmployeeId

คราวนี้ผมก็ได้ temp table เอาไว้ยำข้อมูลแล้วครับ เสร็จแล้วก็อย่าลืม DROP TABLE ด้วยนะ

Referrence
www.stackoverflow.com - How to SELECT * INTO [temp table] FROM [Stored Procedure]

VB.NET เขียนโค้ดควบคุม Object ของ Crystal Report

หลายๆคนที่พัฒนาซอฟท์แวร์ทางธุรกิจก็หนีไม่พ้นที่จะต้องทำรายงาน และที่นิยมมากสำหรับนักพัฒนา .NET ก็คงหนีไม่พ้น Crystal Report นั่นเองครับ ซึ่งใช้งานไม่ยาก ยืดหยุ่น และมีฟังก์ชันมากมายให้ใช้งาน และความยอดเยียมอีกอย่างก็คือ เราสามารถเขียนโค้ดเพื่อควบคุม Crystal Report ได้ด้วย

ลองมาดูตัวอย่างจากคำถามที่ greatfriends ละกันครับ

How to Return total page in crystal report to VB -- HELP ME!!
http://greatfriends.biz/?118103

ปัญหามีอยู่ว่า ผมมี crstal report ที่สร้างออกมาเป็น PDF และก็ต้องเอามก Merge กับ File Attach ที่เป็น PDF ให้เป็น ไฟล์เดียว โดย File ที่ Attach นั้นจะต้องอยู่ตรงกลางระหว่างไฟล์ PDF แรก ซึ่งเลขหน้าเวลา Count จะไม่ถูกต้อง เพราะผม แบ่งไฟล์ PDF แรกเป็นสองส่วน โดยเป็นส่วนหัวและท้าย ซึ่งเวลามัน count page ก็จะแยกกันซึ่งไม่ถูกต้อง คือสมมติ ส่วนหัวมี 10 หน้า และท้าย 5 หน้ามันแสดงเป็น 1 of 10 และ ส่วนท้ายแสดงเป็น 1 of 5 ซึ่งส่วนท้ายต้องเป็น 11 of 15

ผมจึงคิดว่าให้ ส่วนหัว ส่งค่ากลับมาที่ vb ว่ามีจำหน้าทั้งหมดเท่าไหร่ และผมจะส่ง เป็น Parameter ให้กับส่วนท้าย
นะครับ แต่วิธีส่งค่ากลับมาวีบี ทำไงอะครับ ผมรู้สึกว่ามันไม่มีทาง แต่ท่านใดมีแนวทางอื่น ช่วยผมทีครับ

ผมตอบไว้ดังนี้ครับ
สมมติว่าผมสร้าง ITextObject 1 ตัวเอาไว้ที่ Report Footer ของ Crystal Report ตั้งชื่อ txtTotalPage แล้วเอาค่าของ PageNo มาใส่ไว้

ในโค้ด VB

Dim rptDoc As New ReportDocument
rptDoc.FileName = Server.MapPath("~/Reports/Test.rpt")
rptDoc.SetDataSource(DataSet1)
rptDoc.SetParameterValue(0, CDate(Me.txtAsOfDate.Text).ToString("dd MMMM yyyy"))

Dim txtTotalPage As TextObject = TryCast(rptDoc.ReportDefinition.ReportObjects("txtTotalPage"),  CrystalDecisions.CrystalReports.Engine.TextObject)

Dim TotalPage As Integer = 0
If  IsNumeric(txtUSAmount.Text) Then
    TotalPage = CInt(txtUsAmount.Text)
End If

เสร็จแล้วก็เอา TotalPage ไปเป็น Parameter ของ report ตัวที่สอง จากนั้นก็ Export รายงานทั้ง 2 ตัว เป็น pdf แล้วเอามา merge กัน

ทีนี้นอกจาก เราจะอ่านค่าจาก TextObject เรายังสามารถใส่ค่าเข้าไปให้ TextObject ก็ได้ หรือว่าจะกำหนด property อื่นๆ เช่น Top, Width, EnableSuppress ....

ลองดูตัวอย่างครับ

Dim pos As Integer
Dim iCurrency As Integer
Dim txtEUAmount As TextObject = rptDoc.ReportDefinition.ReportObjects("txtEUAmount")
Dim txtEUSum As ReportObject = rptDoc.ReportDefinition.ReportObjects("txtEUSum")

'เรียก function เพื่อตรวจสอบเงื่อนไขสกุลเงิน
If IsContainCurrency(ARStatementOfAccounts, "EUR") Then
     iCurrency += 1
     pos = CalculateObjectPosition(iCurrency) ' เรียกฟังก์ชันสำหรับคำนวณตำแหน่งของ Object ใน Detail
     txtEUAmount.Left = pos
     pos = CalculateSumObjectPosition(iCurrency) 'เรียกฟังก์ชันสำหรับคำนวนตำแหน่งของ Object ใน Group Footer
     txtEUSum.Top = pos
Else
     txtEUAmount.Text = ""
     txtEUSum.ObjectFormat.EnableSuppress = True
End If

pos = 920 + (iCurrency - 1) * 280
DirectCast(rptDoc.ReportDefinition.ReportObjects("LineFV0"), LineObject).Bottom = pos

จะสังเกตุว่ามีการประกาศตัวแปร TextObject และ ReportObject ครับ ซึ่ง ReportObject นั้นเป็น Base Class ของ Object ต่างๆ เช่น LineObject, TextObject ใน Crystal นั่นเอง ดังนั้นถ้าเรารู้ Type แน่นอน เราสามารถทำการ Casting เพื่อกำหนด property เฉพาะของ Type นั้นๆได้ครับ

ก็ไม่ยากใช่ไหมครับ ตอนนี้เราสามารถเขียนโปรแกรมเพื่อทำ Dynamic Layout ของ Crystal Report ได้แล้ว